Sindbad~EG File Manager

%  Tarski-Szmielew's axiom system
%  T is Tarski's B,  non-strict betweenness
%  E is equidistance
%  Names for the axioms as in SST.
%  Assumes key parts of earlier chapters and tries to prove Satz 9.4 


set(hyper_res).
 set(para_into).
 set(para_from).
set(binary_res).
set(ur_res).
%  set(unit_deletion).
set(order_history).
assign(report,5400).
assign(max_seconds, 1000000).
assign(max_mem,2000000).
clear(print_kept).
%set(very_verbose).
set(input_sos_first).
set(ancestor_subsume).
% set(sos_queue).
assign(bsub_hint_wt,-1).
set(keep_hint_subsumers).



assign(max_weight,11).
assign(max_distinct_vars,5).
assign(pick_given_ratio,4).
assign(max_proofs,2).
assign(heat,0).

 

 
list(usable).
 E(x,y,y,x).                                   % A1 from page 10 of sst
 -E(x,y,z,v) | -E(x,y,z2,v2) | E(z,v,z2,v2).   % A2
 -E(x,y,z,z) | x=y.                            % A3
 T(x,y,ext(x,y,w,v)).                          % A4, first half
 E(y,ext(x,y,w,v),w,v).                        % A4, second half
 -E(x,y,x1,y1) | -E(y,z,y1,z1) | -E(x,v,x1,v1) | -E(y,v,y1,v1) |
-T(x,y,z) | -T(x1,y1,z1) | x=y | E(z,v,z1,v1).  % A5
 -T(x,y,x) | x=y.                              % A6
% A7, inner Pasch, two clauses.
-T(xa,xp,xc) | -T(xb,xq,xc) | T(xp,ip(xa,xp,xc,xb,xq),xb).   
-T(xa,xp,xc) | -T(xb,xq,xc) | T(xq,ip(xa,xp,xc,xb,xq),xa).   
-T(alpha,beta,gamma).  %A8,  three lines.
-T(beta,gamma,alpha).
-T(gamma,alpha,beta).
% We don't need more of Tarski's axioms than that here.
E(x,y,x,y).  % Satz2-1
-E(xa,xb,xc,xd) | E(xc,xd,xa,xb).  % Satz2-2
-E(xa,xb,xc,xd) | E(xb,xa,xc,xd).  % Satz2-4
-E(xa,xb,xc,xd) | -E(xc,xd,xe,xf) | E(xa,xb,xe,xf).  %Satz2-3
-E(xa,xb,xc,xd) | E(xa,xb,xd,xc).  % Satz2-5
E(x,x,y,y).  % Satz 2-8
-T(xa,xb,xc) | -T(xa1,xb1,xc1) | -E(xa,xb,xa1,xb1) |
-E(xb,xc,xb1,xc1) | E(xa,xc,xa1,xc1).  % Satz 2.11
xq = xa | -T(xq,xa,u) | -E(xa,u,xc,xd) | ext(xq,xa,xc,xd) = u.    % Satz 2.12
T(x,y,y).    % Satz 3.1
-E(u,v,x,x) | u=v.   % Not one of Szmielew's theorems but we proved it.
-T(xa,xb,xc) | T(xc,xb,xa).  % Satz 3.2.
T(xa,xa,xb).  % Satz 3.3
-T(xa,xb,xc) | -T(xb,xa,xc) | xa = xb.  % Satz 3.4.
-T(xa,xb,xd) | -T(xb,xc,xd) | T(xa,xb,xc). % Satz 3.51.
-T(xa,xb,xd) | -T(xb,xc,xd) | T(xa,xc,xd). % Satz 3.52.
-T(xa,xb,xc) | -T(xa,xc,xd) | T(xb,xc,xd). % Satz 3.61.
-T(xa,xb,xc) | -T(xa,xc,xd) | T(xa,xb,xd). % Satz 3.61.
-T(xa,xb,xc) | -T(xb,xc,xd) | xb = xc | T(xa,xc,xd).  % Satz 3.71
alpha != beta.   %related to Satz 3.14;  easily provable if added to sst3h.in.
-T(xa,xb,xc) | -T(xa,xc,xd) | T(xa,xb,xd). % Satz 3.62.
  -T(xa,xb,xc) | -T(xb,xc,xd) | xb = xc | T(xa,xc,xd).  % Satz 3.71
  -T(xa,xb,xc) | -T(xb,xc,xd) | xb = xc | T(xa,xb,xd).  % Satz 3.72
-IFS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | E(xb,xd,xb1,xd1).  % Satz 4.2
-T(xa,xb,xc) | -T(xa1,xb1,xc1) | -E(xa,xc,xa1,xc1)
 | -E(xb,xc,xb1,xc1) | E(xa,xb,xa1,xb1).  % Satz 4.3

  alpha != beta.  % Satz 3.13
  beta != gamma.
  alpha != gamma.
T(xa,xb,ext(xa,xb,alpha,gamma)).   % Satz 3.14, first half
xb != ext(xa,xb,alpha,gamma).    % Satz 3.14, second half
  % The following many clauses are Definition 4.1
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | T(xa,xb,xc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | T(za,zb,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xa,xc,za,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xb,xc,zb,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xa,xd,za,zd).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xc,xd,zc,zd).
 -T(xa,xb,xc) | -T(za,zb,zc) | -E(xa,xc,za,zc) | -E(xb,xc,zb,zc)
 | -E(xa,xd,za,zd) | -E(xc,xd,zc,zd) | IFS(xa,xb,xc,xd,za,zb,zc,zd).

% Following 4 are definition 4.4 for n=3
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa1,xa2,xb1,xb2).
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa1,xa3,xb1,xb3).
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa2,xa3,xb2,xb3).
-E(xa1,xa2,xb1,xb2) | -E(xa1,xa3,xb1,xb3) | -E(xa2,xa3,xb2,xb3) 
| E3(xa1,xa2,xa3,xb1,xb2,xb3).
% Following three lines are Satz 4.5
-T(xa,xb,xc) | -E(xa,xc,xa1,xc1) | T(xa1,insert(xa,xb,xa1,xc1),xc1).
-T(xa,xb,xc) | -E(xa,xc,xa1,xc1) | E3(xa,xb,xc,xa1,insert(xa,xb,xa1,xc1),xc1).
insert(xa,xb,xa1,xc1) = ext(ext(xc1,xa1,alpha,gamma),xa1,xa,xb).
-E3(x,y,z,u,v,w) | E3(x,z,y,u,w,v).   % See sst4q.in, not in Szmielew
-T(xa,xb,xc) | -E3(xa,xb,xc,xa1,xb1,xc1) | T(xa1,xb1,xc1).  % Satz 4.6

% following is Definition 4.10
-Col(xa,xb,xc) | T(xa,xb,xc) | T(xb,xc,xa) | T(xc,xa,xb).
Col(xa,xb,xc) | -T(xa,xb,xc).
Col(xa,xb,xc) | -T(xb,xc,xa).
Col(xa,xb,xc) | -T(xc,xa,xb).
% Following are Satz 4.11
-Col(x,y,z) | Col(y,z,x).
-Col(x,y,z) | Col(z,x,y).
-Col(x,y,z) | Col(z,y,x).
-Col(x,y,z) | Col(y,x,z).
-Col(x,y,z) | Col(x,z,y).
% following is Satz 4.12
Col(x,x,y).
% following is Satz 4.13
-Col(xa,xb,xc) | - E3(xa,xb,xc,xa1,xb1,xc1) | Col(xa1,xb1,xc1).
% following is Satz 4.14
-Col(xa,xb,xc) | -E(xa,xb,xa1,xb1) | E3(xa,xb,xc,xa1,xb1,insert5(xa,xb,xc,xa1,xb1)).
% following is Definition 4.15
-FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | Col(xa,xb,xc).
-FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | E3(xa,xb,xc,xa1,xb1,xc1).
-FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | E(xa,xd,xa1,xd1).
-FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | E(xb,xd,xb1,xd1).
-Col(xa,xb,xc) | - E3(xa,xb,xc,xa1,xb1,xc1) | - E(xa,xd,xa1,xd1) | -E(xb,xd,xb1,xd1) | FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1).
% Following is Satz 4.16
-FS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | xa = xb | E(xc,xd,xc1,xd1).
% Following is Satz 4.17
xa = xb | -Col(xa,xb,xc) | -E(xa,xp,xa,xq) | -E(xb,xp,xb,xq) | E(xc,xp,xc,xq).
% Following is Satz 4.18
xa = xb | -Col(xa,xb,xc) | -E(xa,xc,xa,xc1) | -E(xb,xc,xb,xc1) | xc = xc1.
% Following is Satz 4.19
-T(xa,xc,xb) | -E(xa,xc,xa,xc1) | -E(xb,xc,xb,xc1) | xc = xc1.
% Following is Satz 5.1
xa = xb | -T(xa,xb,xc) | -T(xa,xb,xd) | T(xa,xc,xd) | T(xa,xd,xc).
% Two lemmas Narboux needed, proved in sst5c.in and sst5d.in
-T(xa,xb,xc) | -E(xa,xc,xa,xb) | xc = xb.
-T(xa,xd,xb) | -T(xa,xe,xb) | -E(xa,xd,xa,xe) | xd=xe. 
% Following is Satz 5.2
xa = xb | -T(xa,xb,xc) | -T(xa,xb,xd)| T(xb,xc,xd) | T(xb,xd,xc).
% Following is Satz 5.3
-T(xa,xb,xd) | -T(xa,xc,xd) | T(xa,xb,xc) | T(xa,xc,xd).
% Following is Definition 5.4
-T(xc,y,xd) | -E(xa,xb,xc,y) | le(xa,xb,xc,xd).
-le(xa,xb,xc,xd) | T(xc,insert(xa,xb,xc,xd),xd). %ab inserted into cd
-le(xa,xb,xc,xd) | E(xa,xb,xc,insert(xa,xb,xc,xd)).
% Following is Satz 5.5a
-le(xa,xb,xc,xd) | T(xa,xb,insert(xc,xd,xa,xb)).
-le(xa,xb,xc,xd) | E(xa,insert(xc,xd,xa,xb),xc,xd).
% Following is Satz 5.5b
-T(xa,xb,x) | -E(xa,x,xc,xd) | le(xa,xb,xc,xd).
% Following is Satz 5.6
-le(xa,xb,xc,xd) | -E(xa,xb,xa1,xb1) | - E(xc,xd,xc1,xd1) | le(xa1,xb1,xc1,xd1).
% Following is Satz 5.7
le(xa,xb,xa,xb).
% Following is Satz 5.8
-le(xa,xb,xc,xd) | - le(xc,xd,xe,xf) | le(xa,xb,xe,xf).
% Following is Satz 5.9
-le(xa,xb,xc,xd) | -le(xc,xd,xa,xb) | E(xa,xb,xc,xd).
% Following is Satz 5.10
le(xa,xb,xc,xd) | le(xc,xd,xa,xb).
% Following is Satz 5.11
le(xa,xa,xc,xd).
% Following is Definition 6.1
sameside(xa,xp,xb) | xa=xp | xb = xp | -T(xp,xa,xb).
sameside(xa,xp,xb) | xa=xp | xb = xp | -T(xp,xb,xa).
-sameside(xa,xp,xb) | xa != xp.
-sameside(xa,xp,xb) | xb != xp.
-sameside(xa,xp,xb) | T(xp,xa,xb) | T(xp,xb,xa).
%Following is Satz 6.2
xa=xp | xb=xp | xc = xp | -T(xa,xp,xc) | -T(xb,xp,xc) | sameside(xa,xp,xb).
xa=xp | xb=xp | xc = xp | -T(xa,xp,xc) | T(xb,xp,xc) | -sameside(xa,xp,xb).
% following is Satz 6.3
-sameside(xa,xp,xb) | xa != xp.
-sameside(xa,xp,xb) | xb != xp.
-sameside(xa,xp,xb) | f63(xa,xp,xb) != xp.
-sameside(xa,xp,xb) | T(xa,xp,f63(xa,xp,xc)).
-sameside(xa,xp,xb) | T(xb,xp,f63(xa,xp,xc)).
xa = xp | xb = xp | xc = xp | -T(xa,xp,xc) | -T(xb,xp,xc) | sameside(xa,xp,xb).
% following is Satz 6.4
-sameside(xa,xp,xb) | Col(xa,xp,xb).
-sameside(xa,xp,xb) | -T(xa,xp,xb).
-Col(xa,xp,xb) | T(xa,xp,xb) | sameside(xa,xp,xb).
% following is Satz 6.5
xa=xp | sameside(xa,xp,xa).
% Following is Satz 6.11
xr = xa | xb = xc | sameside(insert(xb,xc,xa,xr),xa,xr).
xr = xa | xb = xc | E(xa,insert(xb,xc,xa,xr),xb,xc).
xr = xa | xb = xc | -sameside(x,xa,xr) | -sameside(y,xa,xr) | -E(xa,x,xb,xc) | -E(xa,y,xb,xc) | x=y. 
% following is Definition 7.1
-M(xa,xm,xb) | T(xa,xm,xb).
-M(xa,xm,xb) | E(xm,xa,xm,xb).
-T(xa,xm,xb) | - E(xm,xa,xm,xb) | M(xa,xm,xb).
% following is Satz 7.2
-M(xa,xm,xb) | M(xb,xm,xa).
% following is Satz 7.3
-M(xa,xm,xa) | xm=xa.
xm !=xa | M(xa,xm,xa).
% following is half of Satz 7.4, and Definition 7.5
M(xp,xa,s(xa,xp)). 
% following is the uniqueness half of Satz 7.4
-M(xp,xa,xq) | -M(xp,xa,xr) | xq = xr.
% following is Satz 7.6
-M(xp,xa,xq) | s(xa,xp) = xq.
s(xa,xp) != xq | M(xp,xa,xq).
% following is Satz 7.7
s(xa,s(xa,xp)) = xp.
s(xa,xp) != xr | s(xa,xq) != xr | xp = xq.   %Satz 7.8
s(xa,xp) != s(xa,xq) | xp = xq.    % Satz 7.9
s(xa,xp) != xp | xp = xa.   %Satz 7.10a
xp != xa | s(xa,xp)=xp.     % Satz 7.10b
E(xp,xq,s(xa,xp),s(xa,xq)).   % Satz 7.13
-T(xp,xq,xr) | T(s(xa,xp),s(xa,xq),s(xa,xr)).   % Satz 7.15a
T(xp,xq,xr) | -T(s(xa,xp),s(xa,xq),s(xa,xr)).   % Satz 7.15b
-E(xp,xq,xr,xs) | E(s(xa,xp),s(xa,xq),s(xa,xr),s(xa,xs)).  % Satz 7.16a
E(xp,xq,xr,xs) | -E(s(xa,xp),s(xa,xq),s(xa,xr),s(xa,xs)).  % Satz 7.16b
-M(xp,xa,xq) | -M(xp,xb,xq) | xa = xb.   % Satz 7.17
s(xa,xp) != s(xb,xp) | xa = xb.    % Satz 7.18
s(xa,s(xb,xp)) != s(xb,s(xa,xp)) | xa = xb.  % Satz 7.19a
s(xa,s(xb,xp)) = s(xb,s(xa,xp)) | xa != xb.  % Satz 7.19b
-Col(xa,xm,xb) | -E(xm,xa,xm,xb) | xa = xb | M(xa,xm,xb).  % Satz 7.20
% Following 2 lines are Lemma 7.21
Col(xa,xb,xc) | xb = xd | -E(xa,xb,xc,xd) | -E(xb,xc,xd,xa) |
-Col(xa,xp,xc) | -Col(xb,xp,xd) | M(xa,xp,xc).
Col(xa,xb,xc) | xb = xd | -E(xa,xb,xc,xd) | -E(xb,xc,xd,xa) |
-Col(xa,xp,xc) | -Col(xb,xp,xd) | M(xb,xp,xd).
% following is 7.22,  Krippenlemma
-T(xa1,xc,xa2) | -T(xb1,xc,xb2) | -E(xc,xa1,xc,xb1) | -E(xc,xa2,xc,xb2) |
-M(xa1,xm1,xb1) | -M(xa2,xm2,xb2) | T(xm1,xc,xm2).
%following defines a Krippenfigur (definition 7.23)
-T(xa1,xc,xa2) | -T(xb1,xc,xb2) | -E(xc,xa1,xc,xb1) | -E(xc,xa2,xc,xb2) |
-M(xa1,xm1,xb1) | -M(xa2,xm2,xb2) | KF(xa1,xm1,xb1,xc,xb2,xm2,xa2).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) | T(xa1,xc,xa2).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) |  T(xb1,xc,xb2).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) | E(xc,xa1,xc,xb1).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) | E(xc,xa2,xc,xb2).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) | M(xa1,xm1,xb1).
-KF(xa1,xm1,xb1,xc,xb2,xm2,xa2) |  M(xa2,xm2,xb2).
% following is Lemma 7.25
-E(xc,xa,xc,xb) | M(xa,midpoint(xa,xb),xb).

% following is Definition 8.1
-R(xa,xb,xc) | E(xa,xc,xa,s(xb,xc)).
R(xa,xb,xc) | -E(xa,xc,xa,s(xb,xc)).
% following is Satz 8.2
-R(xa,xb,xc) | R(xc,xb,xa).
% following is Satz 8.3
-R(xa,xb,xc) | xa = xb | -Col(xb,xa,xa1) | R(xa1,xb,xc).
% following is Satz 8.4
-R(xa,xb,xc) | R(xa,xb,s(xb,xc)).
% following is Satz 8.5
R(xa,xb,xb).
% following is Satz 8.6
-R(xa,xb,xc) | -R(xa1,xb,xc) | -T(xa,xc,xa1) | xb = xc.
% following is Satz 8.7
-R(xa,xb,xc)| -R(xa,xc,xb) | xb = xc.
% following is Satz 8.8
-R(xa,xb,xa) | xa = xb.
% following is Satz 8.9
-R(xa,xb,xc) | -Col(xa,xb,xc) | xa = xb | xc = xb.
% following is Satz 8.10 
-R(xa,xb,xc) | - E3(xa,xb,xc,xa1,xb1,xc1) | R(xa1,xb1,xc1).
% following is Definition 8.11 
-perpAt(y,z,x,y1,z1) | Col(y,z,x).
-perpAt(y,z,x,y1,z1) | Col(y1,z1,x).
-perpAt(y,z,x,y1,z1) |y != z.
-perpAt(y,z,x,y1,z1) |y1 != z1.
-perpAt(y,z,x,y1,z1) | -Col(y,z,u) | -Col(y1,z1,v) | R(u,x,v).
perpAt(y,z,x,y1,z1) | y = z | y1 = z1 | -Col(y,z,x) | -Col(y1,z1,x) |  Col(y,z,f811(y,z,y1,z1,x)).
perpAt(y,z,x,y1,z1) | y = z | y1 = z1 | -Col(y,z,x) | -Col(y1,z1,x) |  Col(y1,z1,g811(y,z,y1,z1,x)).
perpAt(y,z,x,y1,z1) | y = z | y1 = z1 | -Col(y,z,x) | -Col(y1,z1,x) |  R(f811(y,z,y1,z1,x),x,g811(y,z,y1,z1,x)).
-perp(xp,xq,xp1,xq1) |  perpAt(xp,xq,il(xp,xq,xp1,xq1),xp1,xq1).
perp(xp,xq,xp1,xq1) | -perpAt(xp,xq,x,xp1,xq1).
-perpAt(xp,xq,x,xp1,xq1) | xp != xq.
-perpAt(xp,xq,x,xp1,xq1) | xp1 != xq1.
% following is Satz 8.12a
-perpAt(x,y,z,u,v) | perpAt(u,v,z,x,y).
% following is Satz 8.12b
-perp(x,y,u,v) | perp(u,v,x,y).
% following is Satz 8.13a
-perpAt(xa,xb,x,xp,xq) | xa != xb.
-perpAt(xa,xb,x,xp,xq) | xp != xq.
-perpAt(xa,xb,x,xp,xq) | Col(xa,xb,x).
-perpAt(xa,xb,x,xp,xq) | Col(xp,xq,x).
-perpAt(xa,xb,x,xp,xq) | R(xa,x,xp).   % these four lines give the instantiations found in proving Satz 8.13a, so we don't introduce a new skolem symbol here.
-perpAt(xa,xb,x,xp,xq) | R(xb,x,xp).
-perpAt(xa,xb,x,xp,xq) | R(xa,x,xq).
-perpAt(xa,xb,x,xp,xq) | R(xb,x,xq).
% following is Satz 8.13b
-Col(xa,xb,x) | -Col(xp,xq,x) | xa = xb | xp = xq | -Col(xa,xb,u) |
-Col(xp,xq,v) | u = x |  v = x | -R(u,x,v) | perpAt(xa,xb,x,xp,xq).
% following is Satz 8.14a
-perp(xa,xb,xp,xq) | -Col(xa,xb,xp) | -Col(xa,xb,xq).
% following is Satz 8.14b
-perpAt(xa,xb,xc,xp,xq) | Col(xa,xb,xc).
-perpAt(xa,xb,xc,xp,xq) | Col(xp,xq,xc).
% following is Satz 8.14c
-perpAt(xa,xb,xc,xp,xq) | xc = il(xa,xb,xp,xq).
%following is Satz 8.15a
xa=xb | -Col(xa,xb,x) | -perp(xa,xb,xc,x) | perpAt(xa,xb,x,xc,x).
% following is Satz 8.15b
xa=xb | -Col(xa,xb,x) | perp(xa,xb,xc,x) | -perpAt(xa,xb,x,xc,x).
% following is Satz 8.16a
Col(xa,xb,xc) | -Col(xa,xb,xp) | -Col(xa,xb,xq) | -perp(xa,xb,xc,xp) |
-perp(xa,xb,xc,xq) | xp = xq.
% following is Satz 8.18
Col(xa,xb,xc) | Col(xa,xb,foot(xa,xb,xc)).
Col(xa,xb,xc) | perp(xa,xb,xc,foot(xa,xb,xc)).
Col(xa,xb,xc) | -Col(xa,xb,z) | -Col(xa,xb,y) |  -perp(xa,xb,xc,z) | -perp(xa,xb,xc,y) | y=z.

% following is Lemma 8.20a
-R(xa,xb,xc) | - M(s(xa,xc),xp,s(xb,xc)) | R(xb,xa,xp).
% following is Lemma 8.20b
-R(xa,xb,xc) | - M(s(xa,xc),xp,s(xb,xc)) | -R(xb,xa,xp) | xb = xc | xa != xp. 




% following is Satz 8.21
xa = xb |  perp(xa,xb,erect(xa,xb,xc),xa).
xa = xb |  Col(xa,xb,erectAux(xa,xb,xc)).
xa = xb | T(xc,erectAux(xa,xb,xc),erect(xa,xb,xc)).

% following is Lemma 8.22b  (second half of 8.22 in Szmielew)
-le(xa,xp,xb,xq) | -perp(xa,xb,xa,xp) | -perp(xa,xb,xb,xq) |  -T(xp,xt,xq) | -Col(xa,xb,xt) | M(xa,midpoint(xa,xb),xb).




% Satz 8.22: existence of midpoint:
 M(xa,midpoint(xa,xb),xb).
% following is Lemma 8.24, formulated a little differently than in SST to avoid a new Skolem symbol.
-perp(xp,xa,xa,xb) | -perp(xq,xb,xa,xb) | - Col(xa,xb,xt) | - T(xp,xt,xq) | -T(xb,xr,xq) | -E(xa,xp,xb,xr) | M(xp,midpoint(xa,xb),xr).
% following is Definition 9.1
xp = xq | Col(xp,xq,xa) | Col(xp,xq,xb) | -T(xa,xt,xb) | -Col(xp,xq,xt) | opposite(xa,xp,xq,xb).
-opposite(xa,xp,xq,xb) | -Col(xp,xq,xa).
-opposite(xa,xp,xq,xb) | -Col(xp,xq,xb).
-opposite(xa,xp,xq,xb) | T(xa,il(xa,xb,xp,xq),xb).
-opposite(xa,xp,xq,xb) | Col(xp,xq,il(xa,xb,xp,xq)).
% following is Satz 9.2
-opposite(xa,xp,xq,xb) | opposite(xb,xp,xq,xa).
% following is proved in Ext1.in
xa=xb | -Col(xa,xb,xc) | -Col(xa,xb,xd) | Col(xa,xc,xd).

% The following lemma is needed for Satz9.3a and Satz9.3; we prove it in this file.
% Col(xp,xq,xa) | -Col(xp,xq,xr) | -sameside(xa,xr,xb) | -Col(xp,xq,xb).  %proved in col1.in
 

end_of_list.

 
list(passive).
 
end_of_list.
 
list(sos).   % negation of the lemma 
-Col(p,q,a).
Col(p,q,r).
sameside(a,r,b).
Col(p,q,b).
end_of_list.


list(hints2).

end_of_list.