Sindbad~EG File Manager

%  Tarski-Szmielew's axiom system 
%  T is Tarski's B,  non-strict betweenness
%  E is equidistance
%  Names for the axioms as in SST.
%  This file assumes axioms A4, A5, and Satz 3.6, and the definition of IFS, and Satz 4.2, 4.3, definition 4.4,  Satz 4.5, 4.6, 
%  definition 4.10, and proves Satz 4.11


set(hyper_res).
set(para_into).
set(para_from).
% set(ur_res).
% set(binary_res).
%  set(unit_deletion).
set(order_history).
assign(report,5400).
assign(max_seconds, 1).
assign(max_mem,840000).
clear(print_kept).
%set(very_verbose).
set(input_sos_first).

 
assign(max_weight,25).
assign(max_distinct_vars,11).
assign(pick_given_ratio,4).
assign(max_proofs,40).
assign(heat,0).

weight_list(pick_and_purge).
end_of_list.

list(usable).
E(x,y,y,x).                                   % A1 from page 10 of sst
-E(x,y,z,v) | -E(x,y,z2,v2) | E(z,v,z2,v2).   % A2
  -E(x,y,z,z) | x=y.                            % A3
 T(x,y,ext(x,y,w,v)).                          % A4, first half
 E(y,ext(x,y,w,v),w,v).                        % A4, second half
-E(x,y,x1,y1) | -E(y,z,y1,z1) | -E(x,v,x1,v1) | -E(y,v,y1,v1) 
| -T(x,y,z) | -T(x1,y1,z1) | x=y | E(z,v,z1,v1).  % A5
  -T(x,y,x) | x=y.                              % A6
%  -T(xa,xp,xc) | -T(xb,xq,xc) | T(xp,ip(xa,xp,xc,xb,xq),xb). 
 %A7, first part (inner Pasch)
%  -T(xa,xp,xc) | -T(xb,xq,xc) | T(xq,ip(xa,xp,xc,xb,xq),xa). 
 %A7, second part (inner Pasch)
  -T(alpha,beta,gamma).  %A8,  three lines.
  -T(beta,gamma,alpha).
  -T(gamma,alpha,beta).

  E(x,y,x,y).  % Satz2-1
  -E(xa,xb,xc,xd) | E(xc,xd,xa,xb).  % Satz2-2
  -E(xa,xb,xc,xd) | E(xb,xa,xc,xd).  % Satz2-4
  -E(xa,xb,xc,xd) | -E(xc,xd,xe,xf) | E(xa,xb,xe,xf).  %Satz2-3
  -E(xa,xb,xc,xd) | E(xa,xb,xd,xc).  % Satz2-5
  E(x,x,y,y).  % Satz 2-8
 -T(xa,xb,xc) | -T(xa1,xb1,xc1) | -E(xa,xb,xa1,xb1) | 
     -E(xb,xc,xb1,xc1) | E(xa,xc,xa1,xc1).  % Satz 2.11
  xq = xa | -T(xq,xa,u) | -E(xa,u,xc,xd) | ext(xq,xa,xc,xd) = u.   % Satz 2.12
  -E(u,v,x,x) | u=v.   % Need to prove this
  T(x,y,y).    % Satz 3.1
  -T(xa,xb,xc) | T(xc,xb,xa).  % Satz 3.2.
  T(xa,xa,xb).  % Satz 3.3
 -T(xa,xb,xc) | -T(xb,xa,xc) | xa = xb.  % Satz 3.4.
  -T(xa,xb,xd) | -T(xb,xc,xd) | T(xa,xb,xc). % Satz 3.51.
  -T(xa,xb,xd) | -T(xb,xc,xd) | T(xa,xc,xd). % Satz 3.52.
-T(xa,xb,xc) | -T(xa,xc,xd) | T(xb,xc,xd). % Satz 3.61.
-T(xa,xb,xc) | -T(xa,xc,xd) | T(xa,xb,xd). % Satz 3.62.
  -T(xa,xb,xc) | -T(xb,xc,xd) | xb = xc | T(xa,xc,xd).  % Satz 3.71
  -T(xa,xb,xc) | -T(xb,xc,xd) | xb = xc | T(xa,xb,xd).  % Satz 3.72
-IFS(xa,xb,xc,xd,xa1,xb1,xc1,xd1) | E(xb,xd,xb1,xd1).  % Satz 4.2
-T(xa,xb,xc) | -T(xa1,xb1,xc1) | -E(xa,xc,xa1,xc1)
 | -E(xb,xc,xb1,xc1) | E(xa,xb,xa1,xb1).  % Satz 4.3
 
  alpha != beta.  % Satz 3.13
  beta != gamma.
  alpha != gamma.
T(xa,xb,ext(xa,xb,alpha,gamma)).   % Satz 3.14, first half
xb != ext(xa,xb,alpha,gamma).    % Satz 3.14, second half
  % The following many clauses are Definition 4.1
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | T(xa,xb,xc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | T(za,zb,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xa,xc,za,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xb,xc,zb,zc).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xa,xd,za,zd).
-IFS(xa,xb,xc,xd,za,zb,zc,zd) | E(xc,xd,zc,zd).
 -T(xa,xb,xc) | -T(za,zb,zc) | -E(xa,xc,za,zc) | -E(xb,xc,zb,zc)
 | -E(xa,xd,za,zd) | -E(xc,xd,zc,zd) | IFS(xa,xb,xc,xd,za,zb,zc,zd).

% Following 4 are definition 4.4 for n=3
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa1,xa2,xb1,xb2).
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa1,xa3,xb1,xb3).
-E3(xa1,xa2,xa3,xb1,xb2,xb3) | E(xa2,xa3,xb2,xb3).
-E(xa1,xa2,xb1,xb2) | -E(xa1,xa3,xb1,xb3) | -E(xa2,xa3,xb2,xb3) 
| E3(xa1,xa2,xa3,xb1,xb2,xb3).
% Following three lines are Satz 4.5
-T(xa,xb,xc) | -E(xa,xc,xa1,xc1) | T(xa1,insert(xa,xb,xa1,xc1),xc1).
-T(xa,xb,xc) | -E(xa,xc,xa1,xc1) | E3(xa,xb,xc,xa1,insert(xa,xb,xa1,xc1),xc1).
insert(xa,xb,xa1,xc1) = ext(ext(xc1,xa1,alpha,gamma),xa1,xa,xb).
-T(xa,xb,xc) | -E3(xa,xb,xc,xa1,xb1,xc1) | T(xa1,xb1,xc1).  % Satz 4.6
% following is Definition 4.10
-Col(xa,xb,xc) | T(xa,xb,xc) | T(xb,xc,xa) | T(xc,xa,xb).
Col(xa,xb,xc) | -T(xa,xb,xc).
Col(xa,xb,xc) | -T(xb,xc,xa).
Col(xa,xb,xc) | -T(xc,xa,xb).
 end_of_list.
list(passive).

end_of_list.

list(sos).
Col(a,b,c).
-Col(b,c,a) | -Col(c,a,b) | -Col(c,b,a) | -Col(b,a,c) | -Col(a,c,b).
end_of_list.